     [file docstyle.texi not included]

The Emacs Widget Library
************************

Copyright © 2000--2024 Free Software Foundation, Inc.

     Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.3 or any later version published by the Free Software Foundation; with no Invariant Sections, with the Front-Cover Texts being ``A GNU Manual'', and with the Back-Cover Texts as in (a) below.  A copy of the license is included in the section entitled ``GNU Free Documentation License''.

     (a) The FSF's Back-Cover Text is: ``You have the freedom to copy and modify this GNU manual.''

Introduction
************

Most graphical user interface toolkits provide a number of standard user interface controls (sometimes known as ``widgets'' or ``gadgets''). Emacs doesn't really support anything like this, except for an incredibly powerful text ``widget''.  On the other hand, Emacs does provide the necessary primitives to implement many other widgets within a text buffer.  The widget package simplifies this task.

The basic widgets are:

link
     Areas of text with an associated action.  Intended for hypertext links embedded in text.

push-button
     Like link, but intended for stand-alone buttons.

editable-field
     An editable text field.  It can be either variable or fixed length.

menu-choice
     Allows the user to choose one of multiple options from a menu, where each option is itself a widget.  Only the selected option is visible in the buffer.

radio-button-choice
     Allows the user to choose one of multiple options by activating radio buttons.  The options are implemented as widgets.  All options are visible in the buffer, with the selected one marked as chosen.

item
     A simple constant widget intended to be used in the menu-choice and radio-button-choice widgets.

choice-item
     A button item only intended for use in choices.  When invoked, the user will be asked to select another option from the choice widget.

toggle
     A simple on/off switch.

checkbox
     A checkbox ([ ]/[X]).

editable-list
     Create an editable list.  The user can insert or delete items in the list.  Each list item is itself a widget.

Now, of what possible use can support for widgets be in a text editor? I'm glad you asked.  The answer is that widgets are useful for implementing forms.  A form in Emacs is a buffer where the user is supposed to fill out a number of fields, each of which has a specific meaning.  The user is not supposed to change or delete any of the text between the fields.  Examples of forms in Emacs are the forms package (of course), the customize buffers, the mail and news compose modes, and the HTML form support in the w3 browser.

The advantages for a programmer of using the widget package to implement forms are:

 1. More complex fields than just editable text are supported.

 2. You can give the users immediate feedback if they enter invalid data in a text field, and sometimes prevent entering invalid data.

 3. You can have fixed sized fields, thus allowing multiple fields to be lined up in columns.

 4. It is simple to query or set the value of a field.

 5. Editing happens in the buffer, not in the mini-buffer.

 6. Packages using the library get a uniform look, making them easier for the user to learn.

 7. As support for embedded graphics improve, the Widget library will be extended to use the GUI features.  This means that your code using the Widget library will also use the new graphic features automatically.

User Interface
**************

A form consists of read only text for documentation and some fields, where each field contains two parts, a tag and a value.  The tags are used to identify the fields, so the documentation can refer to the foo field, meaning the field tagged with Foo. Here is an example form:

     Here is some documentation.

     Name: My Name     Choose: This option
     Address:  Some Place
     In some City
     Some country.

     See also _other work_ for more information.

     Numbers: count to three below
     [INS] [DEL] One
     [INS] [DEL] Eh, two?
     [INS] [DEL] Five!
     [INS]

     Select multiple:

     [X] This
     [ ] That
     [X] Thus

     Select one:

     (*) One
     ( ) Another One.
     ( ) A Final One.

     [Apply Form] [Reset Form]

The top level widgets in this example are tagged Name, Choose, Address, _other work_, Numbers, Select multiple, Select one, [Apply Form], and [Reset Form].  There are basically two things the user can do within a form, namely editing the editable text fields and activating the buttons.

Editable Text Fields
====================

In the example, the value for the Name is most likely displayed in an editable text field, and so are values for each of the members of the Numbers list.  All the normal Emacs editing operations are available for editing these fields.  The only restriction is that each change you make must be contained within a single editable text field. For example, capitalizing all text from the middle of one field to the middle of another field is prohibited.

Editable text fields are created by the editable-field widget.

The :format keyword is useful for generating the necessary text; for instance, if you give it a value of "Name: %v ", the Name:  part will provide the necessary separating text before the field and the trailing space will provide the separating text after the field.  If you don't include the :size keyword, the field will extend to the end of the line, and the terminating newline will provide separation after.

The editing text fields are highlighted with the widget-field-face face, making them easy to find.

Buttons
=======

Some portions of the buffer have an associated action, which can be invoked by a standard key or mouse command.  These portions are called buttons.  The default commands for activating a button are widget-button-press and widget-button-click.  The user typically interacts with the buttons with a key, like RET, or with the mouse buttons.

There are several different kind of buttons, all of which are present in the example:

The Option Field Tags
     When you invoke one of these buttons, you will be asked to choose between a number of different options.  This is how you edit an option field.  Option fields are created by the menu-choice widget.  In the example, Choose is an option field tag.

The [INS] and [DEL] buttons
     Activating these will insert or delete elements from an editable list. The list is created by the editable-list widget.

Embedded Buttons
     The _other work_ is an example of an embedded button.  Embedded buttons are not associated with any fields, but can serve any purpose, such as implementing hypertext references.  They are usually created by the link widget.

The [ ] and [X] buttons
     Activating one of these will convert it to the other.  This is useful for implementing multiple-choice fields.  You can create them with the checkbox widget.

The ( ) and (*) buttons
     Only one radio button in a radio-button-choice widget can be selected at any time.  When you invoke one of the unselected radio buttons, it will be selected and the previous selected radio button will become unselected.

The [Apply Form] and [Reset Form] buttons
     These are explicit buttons made with the push-button widget.  The main difference from the link widget is that the buttons will be displayed as GUI buttons when possible.

To make them easier to locate, buttons are emphasized in the buffer with a distinctive face, like widget-button-face or widget-mouse-face.

Navigation
==========

You can use all the normal Emacs commands to move around in a form buffer, plus you will have these additional commands to navigate from widget to widget: widget-forward and widget-backward.

Programming Example
*******************

Here is the code to implement the user interface example (see User Interface).

     (require 'widget)

     (eval-when-compile
       (require 'wid-edit))

     (defvar widget-example-repeat)

     (defun widget-example ()
       "Create the widgets from the Widget manual."
       (interactive)
       (switch-to-buffer "*Widget Example*")
       (kill-all-local-variables)
       (make-local-variable 'widget-example-repeat)
       (let ((inhibit-read-only t))
         (erase-buffer))
       (remove-overlays)
       (widget-insert "Here is some documentation.\n\n")
       (widget-create 'editable-field
                      :size 13
                      :format "Name: %v " ; Text after the field!
                      "My Name")
       (widget-create 'menu-choice
                      :tag "Choose"
                      :value "This"
                      :help-echo "Choose me, please!"
                      :notify (lambda (widget &rest ignore)
                                (message "%s is a good choice!"
                                         (widget-value widget)))
                      '(item :tag "This option" :value "This")
                      '(choice-item "That option")
                      '(editable-field :menu-tag "No option" "Thus option"))
       (widget-create 'editable-field
                      :format "Address: %v"
                      "Some Place\nIn some City\nSome country.")
       (widget-insert "\nSee also ")
       (widget-create 'link
                      :notify (lambda (&rest ignore)
                                (widget-value-set widget-example-repeat
                                                  '("En" "To" "Tre"))
                                (widget-setup))
                      "other work")
       (widget-insert
         " for more information.\n\nNumbers: count to three below\n")
       (setq widget-example-repeat
             (widget-create 'editable-list
                            :entry-format "%i %d %v"
                            :notify
                            (lambda (widget &rest ignore)
                              (let ((old (widget-get widget
                                                     ':example-length))
                                    (new (length (widget-value widget))))
                                (unless (eq old new)
                                  (widget-put widget ':example-length new)
                                  (message "You can count to %d." new))))
                            :value '("One" "Eh, two?" "Five!")
                            '(editable-field :value "three")))
       (widget-insert "\n\nSelect multiple:\n\n")
       (widget-create 'checkbox t)
       (widget-insert " This\n")
       (widget-create 'checkbox nil)
       (widget-insert " That\n")
       (widget-create 'checkbox
                      :notify (lambda (&rest ignore) (message "Tickle"))
                      t)
       (widget-insert " Thus\n\nSelect one:\n\n")
       (widget-create 'radio-button-choice
                      :value "One"
                      :notify (lambda (widget &rest ignore)
                                (message "You selected %s"
                                         (widget-value widget)))
                      '(item "One") '(item "Another One.")
                      '(item "A Final One."))
       (widget-insert "\n")
       (widget-create 'push-button
                      :notify (lambda (&rest ignore)
                                (if (= (length
                                        (widget-value widget-example-repeat))
                                       3)
                                    (message "Congratulation!")
                                  (error "Three was the count!")))
                      "Apply Form")
       (widget-insert " ")
       (widget-create 'push-button
                      :notify (lambda (&rest ignore)
                                (widget-example))
                      "Reset Form")
       (widget-insert "\n")
       (use-local-map widget-keymap)
       (widget-setup))

Widgets Basics
**************

The Widget Library deals with widgets objects.  A widget object has properties whose value may be anything, be it numbers, strings, symbols, functions, etc.  Those properties are referred to as keywords and are responsible for the way a widget is represented in a buffer, and control the way a user or a program can interact with it.

The library defines several widget types, and gives you a way to define new types as well.  In addition, widgets can derive from other types, creating a sort of widget inheritance.  In fact, all widgets defined in the Widget Library share a common parent, the default widget.  In this manual, when we talk about a default behavior, we usually mean the behavior as defined by this default widget. See Widget Gallery, for a description of each defined widget.

Defining a new type that derives from a previous one is not mandatory to create widgets that work very different from a specified type. When creating a widget, you can override any default property, including functions, that control the widget.  That is, you can specialize a widget on creation, without having to define it as a new type of widget.

In addition to the function for defining a widget, this library provides functions to create widgets, query and change its properties, respond to user events and destroy them.  The following sections describe them.

One important property of a widget is its value.  All widgets may have a value,  which is stored in a so-called internal format. For the rest of Emacs, the widget presents its value in a so-called external format.  Both formats can be equal or different, and each widget is responsible for defining how the conversion between each format should happen.

The value property is an important property for almost all widgets, and perhaps more important for editable-field widgets.  This type of widgets allow the user to edit them via the usual editing commands in Emacs.  They can also be edited programmatically. Important: You must call widget-setup after modifying the value of a widget before the user is allowed to edit the widget again.  It is enough to call widget-setup once if you modify multiple widgets.  This is currently only necessary if the widget contains an editing field, but may be necessary for other widgets in the future.

If your application needs to associate some information with the widget objects, for example a reference to the item being edited, it can be done with the widget-put and widget-get functions.  The property names, as shown, are keywords, so they must begin with a :.

Setting Up the Buffer
*********************

To show the widgets in a buffer, you have to create them.  Widget creation is actually a two-step process: conversion and creation per se.  With simple projects, usually the conversion step isn't really important, and you only care about widget creation, so feel free to skip the conversion description until you really need to know it.

Widget conversion is the process that involves taking a widget specification and transforming it into a widget object, suitable to be created, queried and manipulated with other widget functions. Widget creation is the process that takes a widget object and actually inserts it in the buffer.

The simplest function to create a widget is widget-create, which gets a widget specification and returns a widget object.

 -- Function: widget-create type [ keyword argument ]... args
     Create and return a widget of type TYPE, converting it.

     TYPE is a symbol that specifies a widget type.  KEYWORD may be one of the properties supported by the widget type, and ARGUMENT specify the value for that property.  These keyword arguments can be used to overwrite the keyword arguments that are part of TYPE by default, as well as to provide other properties not present in TYPE by default.  ARGS holds additional information for the creation of TYPE and each widget type is responsible for handling that information in a specific way.

     The syntax for the TYPE argument is described in Widget Gallery, and in more detail in every widget where it's relevant.

There are other functions for creating widgets, useful when you work with composite widgets.  That is, widgets that are part of other widgets.

 -- Function: widget-create-child-and-convert parent type &rest args
     Create a widget of type TYPE as a child of PARENT.

     Before creating it, converts TYPE using the keyword arguments provided in ARGS. Adds the :indent property, unless it is already present, and sets it to the sum of the values of: :indent and :offset from PARENT and :extra-offset from TYPE.

     Returns a widget object, with the property :parent set to PARENT.

 -- Function: widget-create-child parent type
     Create a widget of type TYPE as a child of PARENT.

     This function is like widget-create-child-and-convert but it doesn't convert TYPE, so it expects an already converted widget.

 -- Function: widget-create-child-value parent type value
     Create a widget of type TYPE as a child of PARENT with value VALUE.

     This function is like widget-create-child, but it lets you specify a value for the widget.

     Converts VALUE to the internal format, as specified by TYPE, and stores it into the :value property of TYPE. That means, VALUE should be in the external format, as specified by TYPE.

All these creating functions described here use the function stored in the :create property.  So, to modify the creation logic for a widget, you can provide a different :create function.

When you're done creating widgets and you're ready for the user to interact with the buffer, use the function widget-setup.

 -- Function: widget-setup
     Setup the current buffer, so that editable widgets can be edited.

     This should be called after creating all the widgets and before allowing the user to edit them.

As mentioned, all these functions return a widget object.  That widget object can be queried and manipulated with widget functions that take widgets as arguments, until deleting it with the widgets functions available to delete widgets.  Even if you don't save the returned widget object, you still can interact programmatically with the widget.  See Working with Widgets.

 -- Function: widget-delete widget
     Delete the widget WIDGET and remove it from the buffer.

 -- Function: widget-children-value-delete widget
     Delete all children and buttons in widget WIDGET.

     This function does not delete WIDGET itself, only the widgets stored in the :children and :buttons properties.  It also sets those properties to nil.

As with the creation mechanism, the function stored in :delete controls the deletion mechanism for a widget.

Additionally, the library provides a way to make a copy of a widget.

 -- Function: widget-copy widget
     Makes a copy of widget WIDGET and returns it.

     It uses the function stored in the :copy property of WIDGET and returns the widget that that function returns.

As discussed, there is a conversion step when creating a widget.  To do the conversion without actually creating the widget, you can use the widget-convert function.

 -- Function: widget-convert type &rest args
     Convert TYPE to a widget object, using keyword arguments ARGS.

     Returns a widget object, suitable for creation.  It calls the function stored in the :convert-widget property, after putting into the :args property the arguments that the widget in question needs. If TYPE has a :value property, either originally or after doing the conversion, this function converts the value stored in :value to the internal format, and stores it into :value.

Apart from only creating widgets in the buffer, It's useful to have plain text.  For inserting text, the recommended way is with the widget-insert function.

 -- Function: widget-insert &rest args
     Insert ARGS, either strings or characters, at point.

     Uses insert to perform the insertion, passing ARGS as argument.  See Insertion (the Emacs Lisp Reference Manual), for more information about ARGS.

     The resulting text will be read-only.

Working with Widgets
********************

This section covers the more important functions needed to query and manipulate widgets in a generic way.  Widgets may have additional functions for interacting with them, those are described in the description for each widget.  See Widget Gallery.

 -- Function: widgetp widget
     Non-nil if WIDGET is a widget.

 -- Function: widget-type widget
     Return the type of widget WIDGET, a symbol.

     This function is useful to find out which kind of widget WIDGET represents, i.e., the name of the widget type when the widget was created.

 -- Function: widget-member widget property
     Non-nil if widget WIDGET has a value (even nil) for property PROPERTY.

 -- Function: widget-get widget property
     For widget WIDGET, return the value of the property PROPERTY.

     PROPERTY should be a keyword, and the value is what was last set by widget-put for PROPERTY.

 -- Function: widget-put widget property value
     For widget WIDGET, set the property PROPERTY to VALUE. PROPERTY should be a keyword, while VALUE can be anything.

 -- Function: widget-at &optional pos
     Return the widget at position POS, or at point if POS is nil.

 -- Function: widget-field-at pos
     Return the widget field at position POS, or nil if there is none.

 -- Function: widget-apply widget property &rest args
     Apply the function stored in PROPERTY to WIDGET, passing ARGS as additional arguments to the function.

     Returns the result of that function call.

 -- Function: widget-value widget
     Return the current value contained in WIDGET.

     Note that the value returned by this function might differ from what's stored in the :value property of WIDGET.  This is because this function extracts the current value of WIDGET from the buffer, taking editions into account.

     The value returned is in the external format, after getting it with the :value-get function.

     It is an error to call this function on an uninitialized widget.

 -- Function: widget-value-set widget value
     Set the value contained in WIDGET to VALUE.

     Converts VALUE to the internal format, and then sets it by applying the :value-set function.

     It is an error to call this function with an invalid VALUE, that is, a value that WIDGET cannot represent.

 -- Function: widget-default-get widget
     Return the default external value of widget WIDGET.

     The default value is the one stored in :value or the result of applying the :default-get function to the arguments of WIDGET, as stored in :args.  A value of nil is ignored by default, so in order for a widget to respect nil as a value, it has to override the :default-get function.

 -- Function: widget-type-default-get widget
     Convert the :type attribute in WIDGET and return its default value.

 -- Function: widget-child-value-get widget
     Return the value of the first member of :children in WIDGET.

 -- Function: widget-child-value-inline widget
     Return the inline value of the first member of :children in WIDGET.

     The inline value is whatever the function stored in :value-inline returns.

 -- Function: widget-type-value-create widget
     Create a child widget for WIDGET, of type stored in :type.

     Creates the child widget taking the value from the :value property and stores the newly created widget in the :children property of WIDGET.

     The value stored in :type should be an unconverted widget type.

 -- Function: widget-value-convert-widget widget
     Initializes the :value property of WIDGET from :args.

     Sets :args to nil and returns the modified widget WIDGET.

 -- Function: widget-value-value-get widget
     Return the value stored in :value for widget WIDGET.

     This is different to getting the current value for WIDGET with widget-value, since that function extracts the value from the buffer.

 -- Function: widget-apply-action widget &optional event
     Apply the function stored in :action to WIDGET, in response to EVENT.

     It is an error to call this function with an inactive widget.

 -- Function: widget-parent-action widget &optional event
     Tell :parent of WIDGET to handle EVENT.

     Optional EVENT is the event that triggered the action.

 -- Function: widget-child-validate widget
     Check that the first member of :children in WIDGET is valid.

     To be valid means that the widget value passes the checks that the function stored in :validate makes.

 -- Function: widget-children-validate widget
     Check that all :children in WIDGET are valid.

     Returns nil on success, or the first child that isn't valid.

 -- Function: widget-type-match widget value
     Return non-nil if VALUE matches the value for the :type widget.

     As with the other type functions, the widget stored in :type should be an unconverted widget.

 -- Function: widget-types-copy widget
     Copy the :args value in WIDGET and store them in :args.

     Makes the copies by calling widget-copy on each element present in :args.  Returns the modified widget WIDGET.

 -- Function: widget-types-convert-widget widget
     Convert the :args value in WIDGET and store them in args.

     Returns the modified widget WIDGET.

Widgets and the Buffer
**********************

This chapter describes commands that are specific to buffers that contain widgets.

 -- Variable: widget-keymap
     Keymap containing useful bindings for buffers containing widgets.

     Binds TAB to widget-forward and both S-TAB and M-TAB to widget-backward.  It also binds RET to widget-button-press and both down-mouse-1 and down-mouse-2 to widget-button-click.

There's also a keymap for events that the Widget library doesn't need to handle.

 -- Variable: widget-global-map
     Keymap used by widget-button-press and widget-button-click when not on a button.  By default this is global-map.

In addition to these two keymaps, each widget might define a keymap of its own, active when events happen at that widget.

The following navigation commands are available:

TAB
      -- Command: widget-forward &optional count
          Move point COUNT buttons or editing fields forward.

M-TAB
S-TAB
      -- Command: widget-backward &optional count
          Move point COUNT buttons or editing fields backward.

When editing an editable-field widget, the following commands are available:

C-e
      -- Command: widget-end-of-line
          Move point to the end of field or end of line, whichever is first.

C-k
      -- Command: widget-kill-line
          Kill to end of field or end of line, whichever is first.

M-TAB
C-M-i
      -- Command: widget-complete
          Complete the content of the editable field at point.

C-m
RET
      -- Command: widget-field-activate
          Invoke the editable field at point.

The following two commands can execute the action associated with a button widget (e.g., a radio button or checkbox):

RET
C-m
      -- Command: widget-button-press POS &optional EVENT
          Invoke the button at POS, defaulting to point.

          Invocation means to run the function stored in the :action property.

          If point is not located on a button, invoke the binding in widget-global-map (by default the global map).

mouse-2
      -- Command: widget-button-click EVENT
          Invoke the button at the location of the mouse pointer.

          If the mouse pointer is located in an editable text field, invoke the binding in widget-global-map (by default the global map).

          In case the mouse-click is on a widget, calls the function stored in the :mouse-down-action property.

Widget Gallery
**************

All widgets can be created from a type specification.  The general syntax of a type specification is:

     NAME ::= (NAME [KEYWORD ARGUMENT]... ARGS)
          |   NAME

Where NAME is a widget name, as defined with define-widget, KEYWORD is the name of a property and ARGUMENT is the value for that property, and ARGS are interpreted in a widget specific way.  See Defining New Widgets.

Basic Types
===========

The default Widget
------------------

The most basic widget in the Widget Library is the default widget.  It provides the basic behavior for all other widgets, and all its properties are present by default in derived widgets.  You're seldom (if ever) going to effectively create a default widget, but here we describe its properties and behavior, so that we can describe other widgets only by mentioning the properties and behavior those other widgets specialize.

 -- Widget: default
     Widget used as a base for other widgets.

     It provides most of the functionality that is referred to as ``by default'' in this text.  If you want to define a new widget from scratch, use the default widget as its base.

The following keyword arguments apply to all widgets:

:create
     Function to create a widget from scratch.

     The function takes one argument, a widget type, and creates a widget of that type, inserts it in the buffer, and returns a widget object.

     By default, it inserts the widget at point, using the format provided in the :format property.

:delete
     Function to delete a widget.

     The function should take one argument, a widget, and should remove all traces of the widget from the buffer.

     The default value is:

      -- Function: widget-default-delete widget
          Remove WIDGET from the buffer. Delete all :children and :buttons in WIDGET.

     In most cases you should not change this value, but instead use :value-delete to make any additional cleanup.

:value
     The initial value for widgets of this type.

     Typically, a widget represents its value in two formats: external and internal.  The external format is the value as the rest of Emacs sees it, and the internal format is a representation that the widget defines and uses in a widget specific way.

     Both formats might be the same for certain widgets and might differ for others, and there is no guarantee about which format the value stored in the :value property has.  However, when creating a widget or defining a new one (see Defining New Widgets), the :value should be in the external format.

:value-to-internal
     Function to convert the value to the internal format.

     The function takes two arguments, a widget and an external value, and returns the internal value.  The function is called on the present :value when the widget is created, and on any value set later with widget-value-set.

:value-to-external
     Function to convert the value to the external format.

     The function takes two arguments, a widget and an internal value, and returns the value in the external format.

:value-create
     Function to expand the %v escape in the format string.

     It will be called with the widget as its argument and should insert a representation of the widget's value in the buffer.

:value-delete
     A function that should remove the representation of the widget's value from the buffer.

     It will be called with the widget as its argument.  It doesn't have to remove the text, but it should release markers and delete nested widgets if these are not listed in :children or :buttons.

     By default, it's a no-op.

:value-get
     Function to extract the value of a widget, as it is displayed in the buffer.

:value-set
     Function that takes a widget and a value as arguments, and recreates it.

     The value must already be in the internal format for widget.  By default, it deletes the widget with the :delete function and creates it again with the :create function.

:value-inline
     Function that takes a widget and returns its value, inlined.

     Inlined means that if the widget is not inline (i.e., its :inline property is nil), the return value is wrapped in a list.

:default-get
     Function that takes a widget and returns its default value.

     By default, it just returns the value stored in :value.

:format
     This string will be inserted in the buffer when you create a widget. The following % escapes are available:

     %[
     %]
          The text inside will be marked as a button.

          By default, the text will be shown in widget-button-face, and surrounded by brackets.

     %{
     %}
          The text inside will be displayed with the face specified by :sample-face.

     %v
          This will be replaced with the buffer representation of the widget's value.  What this is depends on the widget type.

     %d
          Insert the string specified by :doc here.

     %h
          Like %d, with the following modifications: If the documentation string is more than one line, it will add a button which will toggle between showing only the first line, and showing the full text. Furthermore, if there is no :doc property in the widget, it will instead examine the :documentation-property property.  If it is a lambda expression, it will be called with the widget's value as an argument, and the result will be used as the documentation text.

     %t
          Insert the string specified by :tag here, or the princ representation of the value if there is no tag.

     %%
          Insert a literal %.

:button-face
     Face used to highlight text inside %[ %] in the format.

:button-prefix
:button-suffix
     Strings used as prefix and suffix for widgets that are buttons.

     By default, the values are widget-button-prefix and widget-button-suffix.

     Text around %[ %] in the format.

     These can be

     nil
          No text is inserted.

     a string
          The string is inserted literally.

     a symbol
          The value of the symbol is expanded according to this table.

:doc
     The string inserted by the %d escape in the format string.

:tag
     The string inserted by the %t escape in the format string.

:tag-glyph
     Name of image to use instead of the string specified by :tag on Emacsen that supports it.

:help-echo
     Specifies how to display a message whenever you move to the widget with either widget-forward or widget-backward or move the mouse over it (using the standard help-echo mechanism).

     The value is either a string to display, or a function of one argument, the widget.  If a function, it should return a string to display, or a form that evaluates to such a string.

:follow-link
     Specifies how to interpret a mouse-1 click on the widget. See Defining Clickable Text (the Emacs Lisp Reference Manual).

:indent
     An integer indicating the absolute number of spaces to indent children of this widget.  Its value might be nil too, which corresponds to a value of 0.

     The default :create functions and the functions that create the value per se use this property as a rudimentary layout mechanism for the widgets.

:offset
     An integer indicating how many extra spaces to add to the widget's grandchildren compared to this widget.

:extra-offset
     An integer indicating how many extra spaces to add to the widget's children compared to this widget.

:menu-tag
     Tag used in the menu when the widget is used as an option in a menu-choice widget.

:menu-tag-get
     Function that takes a widget and returns the tag when the widget is used as an option in a menu-choice widget.

     By default, the tag used will be either the :menu-tag or :tag property if present, or the princ representation of the :value property if not.

:match
     Should be a function called with two arguments, the widget and an external value, and should return non-nil if the widget can represent the specified value.

:validate
     A function which takes a widget as an argument, and returns nil if the widget's current value is valid for the widget.

     Otherwise, it should return the widget containing the invalid data, and set that widget's :error property to a string explaining the error.

     By default, it always returns nil.

:tab-order
     Specify the order in which widgets are traversed with widget-forward or widget-backward.  This is only partially implemented.

      a. Widgets with tabbing order -1 are ignored.

      b. (Unimplemented) When on a widget with tabbing order N, go to the next widget in the buffer with tabbing order N+1 or nil, whichever comes first.

      c. When on a widget with no tabbing order specified, go to the next widget in the buffer with a positive tabbing order, or nil

:parent
     The parent of a nested widget (e.g., a menu-choice item or an element of a editable-list widget).

:sibling-args
     This keyword is only used for members of a radio-button-choice or checklist.  The value should be a list of extra keyword arguments, which will be used when creating the radio-button or checkbox associated with this item.

:completions-function
     Function that takes a widget and returns completion data for that widget, like completion-at-point-functions would. See Completion (the Emacs Lisp Reference Manual).  It's used by editable-field widgets to provide completions.

     By default, it looks into the property :completions, which should be a completion table.  If :completions is nil, then it calls the function stored either in the :complete or :complete-function property.

:format-handler
     Function to handle unknown % escapes in the format string.

     It takes a widget and the character that follows the % as arguments.  You can set this to allow your widget to handle non-standard escapes in your own specialized widgets.

     You should end up calling widget-default-format-handler to handle unknown escape sequences, which will handle the %h and any future escape sequences, as well as give an error for unknown escapes.

:button-face-get
     Function to return the face used to fontify a widget button.

     Takes a widget and returns an appropriate face for the widget.  By default, it either returns the face stored in the :button-face property, or calls the :button-face-get function from the parent of the widget, if it has one.

:mouse-face-get
     Function to return the face used to fontify a widget when the mouse pointer hovers over it.

     Takes a widget and returns an appropriate face.  By default, it either returns the face stored in the :mouse-face property, or calls the :button-face-get function from the parent of the widget, if it has one.

:copy
     Function to deep copy a widget type.

     It takes a shallow copy of the widget type as an argument (made by copy-sequence), and returns a deep copy.  The purpose of this is to avoid having different instances of combined widgets share nested attributes.

     Its value by default is identity.

:active
     Function that takes a widget and returns t if it is active.

     A widget might be effectively always active, if its :always-active property is t.

     Widgets can be in two states: active, which means they are modifiable by the user, or inactive, which means they cannot be modified by the user. You can query or set the state with the following code:

          ;; Examine if WIDGET is active or not.
          (if (widget-apply WIDGET :active)
              (message "Widget is active.")
            (message "Widget is inactive.")

          ;; Make WIDGET inactive.
          (widget-apply WIDGET :deactivate)

          ;; Make WIDGET active.
          (widget-apply WIDGET :activate)

     A widget is inactive if it, or any of its ancestors (found by following the :parent link), have been deactivated.  To make sure a widget is really active, you must therefore activate both it and all its ancestors.

          (while widget
            (widget-apply widget :activate)
            (setq widget (widget-get widget :parent)))

     You can check if a widget has been made inactive by examining the value of the :inactive keyword.  If this is non-nil, the widget itself has been deactivated.  This is different from using the :active keyword, in that the latter tells you if the widget or any of its ancestors have been deactivated.  Do not attempt to set the :inactive keyword directly.  Use the :activate :deactivate functions instead.

:activate
     Function that takes a widget and makes it active for user modifications.

:deactivate
     Function that takes a widget and makes it inactive for user modifications.

:action
     Function that takes a widget and optionally an event, and handles a user initiated event.

     By default, uses the :notify function to notify the widget's parent about the event.

:mouse-down-action
     Function that takes a widget and optionally an event, and handles a mouse click on the widget.

     By default, it does nothing.

:notify
     A function called each time the widget or a nested widget is changed.

     The function is called with two or three arguments.  The first argument is the widget itself, the second argument is the widget that was changed, and the third argument is the event leading to the change, if any.

     By default, it passes the notification to the widget's parent.

:prompt-value
     Function to prompt for a value in the minibuffer.

     The function should take four arguments, a widget, a prompt (a string), a value and a boolean, and should return a value for the widget, entered by the user.

     The prompt is the prompt to use.  The value is the default value to use, unless the fourtha argument is non-nil, in which case there is no default value.

     The function should read the value using the method most natural for this widget, and does not have to check that it matches.

The item Widget
---------------

Syntax:

     TYPE ::= (item [KEYWORD ARGUMENT]... VALUE)

A useful widget that holds a constant value, and can be included in other widgets.  Its super is the default widget.

As can be seen in the syntax, the item widget is one of the widget that handles the ARGS argument to widget-create in a specific way.  If present, VALUE is used to initialize the :value property.  When created, it inserts the value as a string in the buffer.

Example:

     (widget-create 'item :tag "Today is" :format "%t: %v\n"
                    (format-time-string "%d-%m-%Y"))

By default, it has the following properties:

:convert-widget
     The function that allows it to handle VALUE.

:value-create
     Prints the representation of :value in the buffer.

:value-get
     Returns the value stored in :value.

:match
     A value matches the item widget if it's equal to its :value.

:match-inline
     Inline values match the item widget if :value is a sublist of values.

:action
     The item widget notifies itself of an event.

:format
     By default, the item widget inserts its tag in the buffer.

The link Widget
---------------

Syntax:

     TYPE ::= (link [KEYWORD ARGUMENT]...  [ VALUE ])

A widget to represent an embedded link.  Its super is the item widget.

The VALUE, if present, is used to initialize the :value property.  The value should be a string, which will be inserted in the buffer.

Example:

     (widget-create 'link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Mail yourself"
                    :action #'(lambda (widget &optional _event)
                                (compose-mail-other-window (widget-value widget)))
                    user-mail-address)

By default, it has the following properties:

:button-prefix
     The value of widget-link-prefix.

:button-suffix
     The value of widget-link-suffix.

:keymap
     A custom keymap for the link widget, so that it can respond to mouse clicks.

:follow-link
     This property allows the link to respect the value of mouse-1-click-follows-link.  See Clickable Text (the Emacs Lisp Reference Manual).

:format
     Buttonizes the link, to make it clickable.

     If you override this property, you should make sure to provide the %[ and %] escape sequences, so that the link is clickable.

By default the link will be shown in brackets.

The url-link Widget
-------------------

Syntax:

     TYPE ::= (url-link [KEYWORD ARGUMENT]...  URL)

A widget to represent a link to a web page.  Its super is the link widget.

It overrides the :action property to open up the URL specified.

Example:

     (widget-create 'url-link
                    :button-prefix ""
                    :button-suffix ""
                    ;; Return appropriate face.
                    :button-face-get (lambda (widget)
                      (if (widget-get widget :visited)
                          'link-visited
                        'link))
                    :format "%[%t%]"
                    :tag "Browse this manual"
                    :action (lambda (widget &optional _event)
                               (widget-put widget :visited t)
                               ;; Takes care of redrawing the widget.
                               (widget-value-set widget (widget-value widget))
                               ;; And then call the original function.
                               (widget-url-link-action widget))
                    "https://www.gnu.org/software/emacs/manual/html_mono/widget.html")

The info-link Widget
--------------------

Syntax:

     TYPE ::= (info-link [KEYWORD ARGUMENT]...  ADDRESS)

A widget to represent a link to an info file.  Its super is the link widget.

It overrides the :action property, to a function to start the built-in Info reader on ADDRESS, when invoked.

Example:

     (widget-create 'info-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Browse this manual"
                    "(widget) info-link")))

The function-link Widget
------------------------

Syntax:

     TYPE ::= (function-link [KEYWORD ARGUMENT]...  FUNCTION)

A widget to represent a link to an Emacs function.  Its super is the link widget.

It overrides the :action property, to a function to describe FUNCTION.

Example:

     (widget-create 'function-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Describe the function that gets called"
                    #'widget-function-link-action)

The variable-link Widget
------------------------

Syntax:

     TYPE ::= (variable-link [KEYWORD ARGUMENT]...  VAR)

A widget to represent a link to an Emacs variable.  Its super is the link widget.

It overrides the :action property, to a function to describe VAR.

Example:

     (widget-create 'variable-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "What setting controls button-prefix?"
                    'widget-button-prefix)

The face-link Widget
--------------------

Syntax:

     TYPE ::= (face-link [KEYWORD ARGUMENT]...  FACE)

A widget to represent a link to an Emacs face.  Its super is the link widget.

It overrides the :action property, to a function to describe FACE.

Example:

     (widget-create 'face-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Which face is this one?"
                    'widget-button)

The file-link Widget
--------------------

Syntax:

     TYPE ::= (file-link [KEYWORD ARGUMENT]...  FILE)

A widget to represent a link to a file.  Its super is the link widget.

It overrides the :action property, to a function to find the file FILE.

Example:

     (let ((elisp-files (directory-files user-emacs-directory t ".el$")))
       (dolist (file elisp-files)
         (widget-create 'file-link
                        :button-prefix ""
                        :button-suffix ""
                        file)
         (widget-insert "\n")))

The emacs-library-link Widget
-----------------------------

Syntax:

     TYPE ::= (emacs-library-link [KEYWORD ARGUMENT]...  FILE)

A widget to represent a link to an Emacs Lisp file.  Its super is the link widget.

It overrides the :action property, to a function to find the file FILE.

Example:

     (widget-create 'emacs-library-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Show yourself, Widget Library!"
                    "wid-edit.el")

The emacs-commentary-link Widget
--------------------------------

Syntax:

     TYPE ::= (emacs-commentary-link [KEYWORD ARGUMENT]...  FILE)

A widget to represent a link to the Comment section of an Emacs Lisp file.  Its super is the link widget.

It overrides the :action property, to a function to find the file FILE and put point in the Comment section.

Example:

     (widget-create 'emacs-commentary-link
                    :button-prefix ""
                    :button-suffix ""
                    :tag "Check our good friend Customize"
                    "cus-edit.el")

The push-button Widget
----------------------

Syntax:

     TYPE ::= (push-button [KEYWORD ARGUMENT]...  [ VALUE ])

A widget that acts as a pushable button.  Its super is the item widget.

The VALUE, if present, is used to initialize the :value property.  The value should be a string, which will be inserted in the buffer.

By default, it has the following properties:

:button-prefix
     The empty string.

:button-suffix
     The empty string.

:value-create
     Inserts a representation of the ``on'' and ``off'' states for the push button.

     The representation might be an image, stored in the :tag-glyph property, or text.  If it is text, it might be the value of the :tag property, or the :value of the widget, surrounded with widget-push-button-prefix and widget-push-button-suffix.  See Customization.

:format
     Buttonizes the widget, to make it clickable.

The editable-field Widget
-------------------------

Syntax:

     TYPE ::= (editable-field [KEYWORD ARGUMENT]... [ VALUE ])

A widget that can be edited by the user.  Its super is the default widget.

The VALUE, if present, is used to initialize the :value property.  The value should be a string, which will be inserted in the field.  If not present, :value is the empty string.

Warning: In an editable-field widget, the editable field must not be adjacent to another widget---that won't work. You must put some text in between.  Either make this text part of the editable-field widget itself, or insert it with widget-insert.

This widget either overrides or adds the following properties:

:convert-widget
     Just like the item widget, this function allows it to initialize :value from VALUE.

:keymap
     Keymap used in the editable field.

     The default value is widget-field-keymap, which allows the user to use all the normal editing commands, even if the buffer's major mode suppresses some of them.  Pressing RET invokes the function specified by :action.

:format
     By default, it specifies to insert only the widget's value.

     Warning: In an editable-field widget, the %v escape must be preceded by some other text in the :format string (if specified).

:size
     The width of the editable field.

     By default the field will reach to the end of the line.

:value-face
     Face used for highlighting the editable field.

     Default is widget-field-face, see User Interface.

:secret
     Character used to display the value.

     You can set this to, e.g., ?* if the field contains a password or other secret information.  By default, this is nil, and the value is not secret.

:valid-regexp
     By default the :validate function will match the content of the field with the value of this attribute.

     The default value is "" which matches everything.

:validate
     Returns nil if the current value of the widget matches the :valid-regexp value.

:prompt-internal
     A function to read a value for widget, used by the :prompt-value function.

:prompt-history
     A variable that holds the history of field minibuffer edits.

:prompt-value
     A function that uses the :prompt-internal function and the :prompt-history value to prompt for a string, and return the user response in the external format.

:action
     When invoked, moves point to the next field.

:value-create
     Function that takes care of creating the widget, respecting its :size and :value.

:value-set
     Function to use to modify programmatically the current value of the widget.

:value-delete
     Function that removes the widget so it cannot be edited anymore.

:value-get
     Function to return the current text in the widget.

     It takes an optional argument, NO-TRUNCATE.  If NO-TRUNCATE is nil, truncates trailing spaces.

:match
     Function that makes the widget match any string value.

The text Widget
---------------

Syntax:

     TYPE ::= (text [KEYWORD ARGUMENT]... [ VALUE ])

A widget just like the editable-field widget, but intended for multiline text fields.  Its super is the editable-field widget.

It overrides the following properties:

:format
     By default, prints a tag and the value.

:keymap
     The default is widget-text-keymap, which does not rebind the RET key.

The menu-choice Widget
----------------------

Syntax:

     TYPE ::= (menu-choice [KEYWORD ARGUMENT]... TYPE ... )

A widget to represent a menu of options.  Its super is the default widget.

The TYPE argument represents each possible choice.  The widget's value will be that of the chosen TYPE argument.

It either overrides or adds the following properties:

:convert-widget
     A function that takes care of converting each possible choice.

:copy
     A function to copy each possible choice.

:format
     By default, buttonize the tag and show the value.

:void
     Widget type used as a fallback when the value does not match any of the specified TYPE arguments.

     By default this is an item widget.

:case-fold
     If nil don't ignore case when prompting for a choice through the minibuffer.

     By default, its value is t.

:children
     A list whose CAR is the widget representing the currently chosen type in the buffer.

:choice
     The current chosen type.

:args
     The list of types.

:value-create
     The function that inserts the current value for the widget.

     It inserts the first choice that matches, as with the :match function, the value of the widget.

:value-get
     Returns the value of the first child for the widget (see the description for :children above).

:value-inline
     Returns the inline value of the first child for the widget.

:default-get
     The default value for this widget is the default value for the first choice, in case :value is missing.

     This means that if you want a specific default value for the menu-choice widget, you should either pass a :value property when creating it, or arrange the choices so that the first one can hold your desired default value.

:mouse-down-action
     A function that takes care of showing a menu, if possible and desired.

:action
     A function that takes care of getting a new choice for the widget.

     Depending on the number of choices available, it may show a menu or just toggle the choices, or even do nothing at all.

     After getting the choice, it recreates the widget and notifies it.

:validate
     Returns nil if the widget's value is a valid choice.

:match
     This widget will match any value matching at least one of the specified TYPE arguments.

:match-inline
     A function that returns non-nil if the values match the widget, taking into account the :inline property.

The radio-button-choice Widget
------------------------------

Syntax:

     TYPE ::= (radio-button-choice [KEYWORD ARGUMENT]...  TYPE ... )

A widget to represent a choice from multiple options.  Its super is the default widget.

The component TYPES specify the choices, with one radio button for each.  The widget's value will be that of the chosen TYPE argument.

It overrides the following properties:

:convert-widget
     As other composite widgets, a function that takes care of converting each available choice.

:copy
     A function to copy each available choice.

:action
     A function that checks if any radio button was pressed and activates the pressed one, possibly deactivating an old one.  Then, it notifies itself.

:entry-format
     This string will be inserted for each entry in the list. The following % escapes are available:

     %v
          Replace with the buffer representation of the TYPE widget.

     %b
          Replace with the radio button.

     %%
          Insert a literal %.

:format
     By default, it inserts its value.

:button-args
     A list of keywords to pass to the radio buttons.  Useful for setting, e.g., the :help-echo for each button.

:buttons
     The widgets representing the radio buttons.

:children
     The widgets representing each type.

:choice
     The current chosen type.

:args
     The list of types.

:value-create
     A function to insert all available choices.

:value-get
     Returns the value for the chosen widget.

:value-set
     A function to set the value to one of its available options.

:value-inline
     A function that returns the inline value of the child widget.

:offset
     By default, this widget has an offset of 4.

:validate
     The widget validates if the current value is valid for one of its children.

:match
     This widget matches any value that matches at least one of the specified TYPE arguments.

:match-inline
     Like the :match function, but taking into account inline values.

You can add extra radio button items to a radio-button-choice widget after it has been created with the function widget-radio-add-item.

 -- Function: widget-radio-add-item widget type
     Add to radio-button-choice widget WIDGET a new radio button item of type TYPE.

Please note that such items added after the radio-button-choice widget has been created will not be properly destructed when you call widget-delete.

The choice-item Widget
----------------------

Syntax:

     ITEM ::= (choice-item [KEYWORD ARGUMENT]... VALUE)

A widget to represent a choice in a menu-choice widget.  Its super is the item widget.

The VALUE, if present, is used to initialize the :value property.

It overrides the following properties:

:action
     Activating the button of a choice-item is equivalent to activating the parent widget.

:format
     By default, it buttonizes the tag (i.e., its value) and adds a newline character at the end of the widget.

The toggle Widget
-----------------

Syntax:

     TYPE ::= (toggle [KEYWORD ARGUMENT]...)

A widget that can toggle between two states.  Its super is the item widget.

The widget has two possible states, on and off, which correspond to a t or nil value, respectively.

Example:

     (widget-insert "Press the button to activate/deactivate the field: ")
     (widget-create 'toggle
                    :notify (lambda (widget &rest _ignored)
                               (widget-apply widget-example-field
                                             (if (widget-value widget)
                                                 :activate
                                               :deactivate))))
     (widget-insert "\n")

     (setq widget-example-field
           (widget-create 'editable-field
                          :deactivate (lambda (widget)
                                        (widget-specify-inactive
                                         widget
                                         (widget-field-start widget)
                                         (widget-get widget :to)))))
     (widget-apply widget-example-field :deactivate)))

It either overrides or adds the following properties:

:format
     By default, it buttonizes the value and adds a newline at the end of the widget.

:on
     A string representing the on state.  By default the string on.

:off
     A string representing the off state.  By default the string off.

:on-glyph
     Name of a glyph to be used instead of the :on text string, on emacsen that supports this.

:off-glyph
     Name of a glyph to be used instead of the :off text string, on emacsen that supports this.

:value-create
     A function for creating the widget's value, according to its :on or :off state.

:action
     Function to toggle the state of the widget.  After toggling, it notifies itself.

:match
     This widget matches anything.

The radio-button-toggle Widget
------------------------------

Syntax:

     TYPE ::= (radio-button-toggle [KEYWORD ARGUMENT]...)

A toggle to use in the radio widget.

It overrides the following properties:

:button-prefix
     The empty string.

:button-suffix
     The empty string.

:on
     The string ``(*)'', to represent the on state.

:off
     The string ``( )'', to represent the off state.

:on-glyph
     The name of an image to represent the on state.

:off-glpyh
     The name of an image to represent the off state.

:format
     By default, it buttonizes its value.

:notify
     A function to notify its parent.

The checkbox Widget
-------------------

Syntax:

     TYPE ::= (checkbox [KEYWORD ARGUMENT]...)

A widget to represent a toggle widget, with a checkbox.  Its super is the toggle widget.

This widget has two possible states, selected and unselected, which corresponds to a t or nil value, respectively.

It either overrides or adds the following properties:

:button-prefix
     The empty string.

:button-suffix
     The empty string.

:format
     By default, buttonizes the value.

:on
     By default, the string ``[X]''.

:off
     By default, the string ``[ ]''.

:on-glyph
     The name of the image to use when the state is on.

:off-glyph
     The name of the image to use when the state is off.

:action
     A function that toggles the checkbox, notifies the parents and in the on state, activates its siblings.

The checklist Widget
--------------------

Syntax:

     TYPE ::= (checklist [KEYWORD ARGUMENT]...  TYPE ... )

A widget to represent a multiplice choice.  Its super is the default widget.

The TYPE arguments represent each checklist item.  The widget's value will be a list containing the values of all checked TYPE arguments.

Example:

     (widget-create 'checklist
                    :notify (lambda (widget child &optional _event)
                              (funcall
                                (widget-value (widget-get-sibling child))
                                'toggle))
                    :value (list 'tool-bar-mode 'menu-bar-mode)
                    '(item :tag "Tool-bar" tool-bar-mode)
                    '(item :tag "Menu-bar" menu-bar-mode))))

It either overrides or adds the following properties:

:convert-widget
     As other composite widgets, a function that takes care of converting each checklist item.

:copy
     A function to copy each checklist item.

:format
     By default, it inserts its value.

:entry-format
     This string will be inserted for each entry in the list. The following % escapes are available:

     %v
          Replaced with the buffer representation of the TYPE widget.

     %b
          Replace with the checkbox.

     %%
          Insert a literal %.

:button-args
     A list of keywords to pass to the checkboxes.  Useful for setting, e.g., the :help-echo for each checkbox.

:buttons
     The widgets representing the checkboxes.

:children
     The widgets representing each type.

:args
     The list of types.

:value-create
     The function that takes care of inserting all values.

:value-get
     A function that returns all values of selected items.

:validate
     A function that ensures all selected children are valid.

:match
     The checklist widget will match a list whose elements all match at least one of the specified TYPE arguments.

:match-inline
     Like the :match function, but taking into account the :inline property.

:greedy
     Usually a checklist will only match if the items are in the exact sequence given in the specification.  By setting :greedy to non-nil, it will allow the items to come in any sequence. However, if you extract the value they will be in the sequence given in the checklist, i.e., the original sequence is forgotten.

The editable-list Widget
------------------------

Syntax:

     TYPE ::= (editable-list [KEYWORD ARGUMENT]... TYPE)

A widget that can hold a variable list of widgets of the same type, represented by TYPE.  Its super is the default widget.

It either overrides or adds the following properties:

:convert-widget
     As other composite widgets, a function that takes care of converting each type in TYPE.

:copy
     A function to copy the types given in TYPE.

:entry-format
     This string will be inserted for each entry in the list. The following % escapes are available:

     %v
          This will be replaced with the buffer representation of the TYPE widget.

     %i
          Insert the [INS] button, a widget of type insert-button.

     %d
          Insert the [DEL] button, a widget of type delete-button.

     %%
          Insert a literal %.

:insert-button-args
     A list of keyword arguments to pass to the insert buttons.

:delete-button-args
     A list of keyword arguments to pass to the delete buttons.

:append-button-args
     A list of keyword arguments to pass to the trailing insert button.

:buttons
     The widgets representing the insert and delete buttons.

:format
     By default, insert its value and at the and adds an insert button.

     This is useful so that new elements can be added to the list upon user request.

:format-handler
     A function that recognize the escape for inserting an insert button.

:offset
     By default, this widget has an offset of 12.

:children
     The widgets representing the elements of the list.

:args
     List whose CAR is the type of the list elements.

:insert-before
     Function to insert a new widget as a child of the editable-list widget.

     This function inserts a recently deleted child, if there is one.  That is useful, so that the user can move elements in a list easily.  If there is not a recently deleted child, it inserts a child with its default value.

:delete-at
     Function to delete a child from the widget, and store it into the :last-deleted list, so that it can be reinserted when the :insert-before function executes.

:value-create
     The function that takes care of inserting all values.

:value-get
     Function that returns a list with the value of the child widgets.

:validate
     This widget validates if all children validate.

:match
     To match, the value must be a list and all the list members must match the specified TYPE.

:match-inline
     Like the :match function, but taking into account inline values and widgets.

The group Widget
----------------

Syntax:

     TYPE ::= (group [KEYWORD ARGUMENT]... TYPE...)

A widget to group other widgets.  Its super is the default widget.

Its value is a list, with one member for each TYPE.

It overrides the following properties:

:convert-widget
     As other composite widgets, a function that takes care of converting each widget in TYPE.

:copy
     A function to copy the types given in TYPE.

:format
     By default, displays a newline character and its value.

:value-create
     A function to create each of its components.

:value-get
     The same function used by the editable-list widget.

:default-get
     A function that returns a list whose members are the default values of each widget it groups.

:validate
     This widget validates if all of its children validate.

:match
     This widget matches a value that matches each of its components.

:match-inline
     As :match, but taking into account widgets and values that are inline.

The documentation-string Widget
-------------------------------

Syntax:

     TYPE ::= (documentation-string [KEYWORD ARGUMENT]... VALUE)

A widget to represent a documentation string.  Its super is the item widget.

It either overrides or adds the following properties:

:format
     By default, insert its value.

:value-create
     Function to insert a documentation string, possibly hiding part of the documentation if its large.

     To show or hide the rest of the documentation, uses a visibility widget.

:action
     Function to toggle showing the documentation upon an event.

:visibility-widget
     A symbol, the type of the widget to use for the visibility widget.

     This is, by default, the symbol visibility.

Sexp Types
==========

A number of widgets for editing s-expressions (Lisp types), sexp for short, are also available.  These basically fall in several categories described in this section.

The Constant Widgets
--------------------

The const widget can contain any Lisp expression, but the user is prohibited from editing it, which is mainly useful as a component of one of the composite widgets.

The syntax for the const widget is:

     TYPE ::= (const [KEYWORD ARGUMENT]...  [ VALUE ])

Its super is the item widget.  The VALUE, if present, is used to initialize the :value property and can be any s-expression.

 -- Widget: const
     This will display any valid s-expression in an immutable part of the buffer.

     It overrides the :prompt-value function, to avoid prompting and just return the widget's value.

There are two variations of the const widget, namely variable-item and function-item.  These should contain a symbol with a variable or function binding, respectively.  The major difference from the const widget is that they will allow the user to see the variable or function documentation for the symbol.

This is accomplished via using the %h format escape, and adding an appropriate :documentation-property function for each widget.

 -- Widget: variable-item
     An immutable symbol that is bound as a variable.

 -- Widget: function-item
     An immutable symbol that is bound as a function.

Generic Sexp Widget
-------------------

The sexp widget can contain any Lisp expression, and allows the user to edit it inline in the buffer.

The syntax for the sexp widget is:

     TYPE ::= (sexp [KEYWORD ARGUMENT]...  [ VALUE ])

 -- Widget: sexp
     This widget represents an editable field that's useful to edit any valid s-expression.

     The sexp widget takes the same keyword arguments as the editable-field widget.  See editable-field.

     Its default value is nil.

 -- Widget: restricted-sexp
     A widget to edit Lisp expressions restricted to certain values or types.  Its super is the sexp widget.

     It works just like the sexp widget, but it overrides the :match function to match for certain values.  To use this widget, either you must define a :match function or give a :match-alternatives property.  The :match-alternatives property holds a list of predicate functions to call when checking if a given value matches the widget.  Each predicate function will be called with one argument, the value to be matched, and should return non-nil on success.

     As an example, the integer widget overrides :match-alternatives to (integerp).

Atomic Sexp Widgets
-------------------

The atoms are s-expressions that do not consist of other s-expressions. For example, a string, a file name, or a symbol are atoms, while a list is a composite type.  You can edit the value of an atom with the widgets described in this section.

The syntax for all the atoms is:

     TYPE ::= (CONSTRUCT [KEYWORD ARGUMENT]...  [ VALUE ])

The VALUE, if present, is used to initialize the :value property and must be an expression of the same type as the widget. That is, for example, the string widget can only be initialized with a string.

All the atom widgets take the same keyword arguments as the editable-field widget.  See editable-field.

 -- Widget: string
     An editable field widget that can represent any Lisp string.

     It offers completion via the ispell library and the :complete property.

 -- Widget: regexp
     An editable field widget that can represent a regular expression.

     Overrides the :match and the :validate properties to check that the value is a valid regexp.

 -- Widget: character
     An editable field widget that can represent a character.

     The character widget represents some characters (like the newline character) in a special manner, to make it easier for the user to see what's the content of the character field.

 -- Widget: file
     A widget for editing file names.

     Keywords:

     :completions
          Offers file name completion to the user.

     :prompt-value
          A function to read a file name from the minibuffer.

     :must-match
          If this is set to non-nil, only existing file names are allowed when prompting for a value in the minibuffer.

     :match
          The widget matches if the value is a string, and the file whose name is that string is an existing file, or if :must-match is nil.

     :validate
          The widget is valid if its value matches.

 -- Widget: directory
     A widget for editing directory names.

     Its super is the file widget, and it overrides the :completions property, to offer completions only for directories.

 -- Widget: symbol
     A widget for editing a Lisp symbol.

     Its value by default is nil.

 -- Widget: function
     A widget for editing a lambda expression, or a function name, offering completion.  Its super is the restricted-sexp widget.

 -- Widget: variable
     A widget for editing variable names, offering completion.  Its super is the symbol widget.

 -- Widget: integer
     A widget for editing integers in an editable field.  Its super is the restricted-sexp widget.

     It has a default :value of 0.

 -- Widget: natnum
     A widget for editing non-negative integers.  Its super is the restricted-sexp widget.

     It has a default :value of 0.

 -- Widget: float
     A widget for editing a floating point number.  Its super is the restricted-sexp widget.

     It has a default :value of 0.0.

 -- Widget: number
     A widget for editing a number, either floating point or integer.  Its super is the restricted-sexp widget.

     It has a default :value of 0.0.

 -- Widget: boolean
     A widget for editing a boolean value.  Its super is the toggle widget.

     Its value may be nil, meaning false, or non-nil, meaning true.

 -- Widget: color
     A widget to edit a color name.

     In addition, shows a sample that shows the selected color, if any.

 -- Widget: other
     A widget useful as the last item in a choice widget, since it matches any value.

     Its super is the sexp widget, and its :value is other, by default.

 -- Widget: coding-system
     A widget that can represent a coding system name, offering completions.  See Coding Systems (the Emacs Lisp Reference Manual).  Its super is the symbol widget.

     It has a default value of undecided.

 -- Widget: key
     A widget to represent a key sequence.

     It uses a special keymap as the :keymap.

Composite Sexp Widgets
----------------------

The syntax for the composite widget construct is:

     TYPE ::= (CONSTRUCT [KEYWORD ARGUMENT]...  COMPONENT...)

where each COMPONENT must be a widget type.  Each component widget will be displayed in the buffer, and will be editable by the user.

 -- Widget: cons
     A widget to edit cons-cell values.  Its super is the group widget.

     The value of a cons widget must be a cons-cell whose CAR and CDR have two specified types.  It uses this syntax:

          TYPE ::= (cons [KEYWORD ARGUMENT]...  CAR-TYPE CDR-TYPE)

 -- Widget: choice
     A widget to hold a value of one of a fixed set of types.  Its super is the menu-choice widget.

     The widget's syntax is as follows:

          TYPE ::= (choice [KEYWORD ARGUMENT]...  TYPE ... )

     The value of a choice widget can be anything that matches any of the TYPES.

     This widget only displays the widget that corresponds to the current choice.

 -- Widget: radio
     A widget to hold a value of one of a fixed set of options.  Its super is the radio-button-choice widget.

 -- Widget: list
     A widget to edit a list value.  Its super is the group widget.

     The value of a list widget must be a list whose element types match the specified component types:

          TYPE ::= (list [KEYWORD ARGUMENT]...  COMPONENT-TYPE...)

     Thus, for example, (list string number) matches lists of two elements, the first being a string and the second being a number.

 -- Widget: vector
     A widget to edit a vector value.  Its super is the group widget.

     The vector widget is like the list widget but matches vectors instead of lists.  Thus, for example, (vector string number) matches vectors of two elements, the first being a string and the second being a number.

The above suffice for specifying fixed size lists and vectors.  To get variable length lists and vectors, you can use a choice, set, or repeat widget together with the :inline keyword.  If any component of a composite widget has the :inline keyword set, its value must be a list which will then be spliced into the composite.  For example, to specify a list whose first element must be a file name, and whose remaining elements should either be the symbol t or two strings (file names), you can use the following widget specification:

     (list file
           (choice (const t)
                   (list :inline t
                         :value ("foo" "bar")
                         string string)))

The value of a widget of this type will either have the form (file t) or (file STRING STRING).

This concept of :inline may be hard to understand.  It was certainly hard to implement, so instead of confusing you more by trying to explain it here, I'll just suggest you meditate over it for a while.

 -- Widget: set
     A widget to hold a list of members from a fixed set.  Its super is the checklist widget.

     Its value is a list where the elements all belong to a given set.  The order of elements of the list is not significant.

     Here's the syntax:

          TYPE ::= (set [KEYWORD ARGUMENT]...  PERMITTED-ELEMENT ... )

     Use const to specify each permitted element, like this: (set (const a) (const b)).

 -- Widget: repeat
     Specifies a list of any number of elements that fit a certain type. Its super is the editable-list widget.

          TYPE ::= (repeat [KEYWORD ARGUMENT]...  TYPE)

 -- Widget: plist
     A widget to edit property lists.  Its super is the list widget.

     It recognizes the following properties:

     :options
          A given set of recommended key-value values for the plist widget.  Each option shows up as a checklist item.

     :key-type
          The widget type to use for the plist keys.  By default, it uses the symbol widget.

     :value-type
          The widget type to use for the plist values.  By default, it uses the sexp widget.

 -- Widget: alist
     A widget to edit association lists.  Its super is the list widget.

     It recognizes the same properties that the plist widget, with the difference that the :key-type uses by default a sexp widget.

Most composite widgets do not allow for recursion.  That is, none of the contained widgets may be of the same type that is currently being defined.  To allow for this kind of widgets, there's the lazy widget.

 -- Widget: lazy
     A base widget for recursive data structures.  Its super is the default widget.

     When instantiated, it contains a single inferior widget of the widget type specified in the :type property.  Its value is the same as the value of this inferior widget.

Defining New Widgets
********************

You can define specialized widgets with define-widget.  It allows you to create a shorthand for more complex widgets, including specifying component widgets and new default values for the keyword arguments.

 -- Function: define-widget name class doc &rest args
     Define a new widget type named NAME that derives from CLASS.

     NAME and CLASS should both be symbols, and CLASS should be one of the existing widget types.

     The third argument DOC is a documentation string for the widget.

     ARGS should be key-value pairs, overriding keyword values of CLASS, or adding new recognized keywords for NAME.

     Usually, you'll want to derive from an existing widget type, like the editable-field widget, or the default widget, but it's also possible to derive from nothing, by passing a value of nil as CLASS.  Note that if you do this, you're entirely responsible for defining a whole new default behavior for your widgets.

     After using this function, the following two calls will create identical widgets:

       * (widget-create NAME)

       * (apply widget-create CLASS ARGS)

Using define-widget just stores the definition of the widget type in the widget-type property of NAME, which is what widget-create uses.

If you only want to specify defaults for keywords with no complex conversions, you can use identity as your conversion function.

When defining new widgets, the :convert-widget property might be useful:

:convert-widget
     Function to convert a widget type before creating a widget of that type.

     It takes a widget type as an argument, and returns the converted widget type.  When a widget is created, this function is called for the widget type and all the widget's parent types, most derived first.

     The predefined functions widget-types-convert-widget and widget-value-convert-widget can be used here.

Example:

     (defvar widget-ranged-integer-map
       (let ((map (copy-keymap widget-keymap)))
         (define-key map [up] #'widget-ranged-integer-increase)
         (define-key map [down] #'widget-ranged-integer-decrease)
         map))

     (define-widget 'ranged-integer 'integer
       "A ranged integer widget."
       :min-value most-negative-fixnum
       :max-value most-positive-fixnum
       :keymap widget-ranged-integer-map)

     (defun widget-ranged-integer-change (widget how)
       "Change the value of the ranged-integer WIDGET, according to HOW."
       (let* ((value (widget-value widget))
              (newval (cond
                       ((eq how 'up)
                        (if (< (1+ value) (widget-get widget :max-value))
                            (1+ value)
                          (widget-get widget :max-value)))
                       ((eq how 'down)
                        (if (> (1- value) (widget-get widget :min-value))
                            (1- value)
                          (widget-get widget :min-value)))
                       (t (error "HOW has a bad value"))))
              (inhibit-read-only t))
         (widget-value-set widget newval)))

     (defun widget-ranged-integer-increase (widget)
       "Increase the value of the ranged-integer WIDGET."
       (interactive (list (widget-at)))
       (widget-ranged-integer-change widget 'up))

     (defun widget-ranged-integer-decrease (widget)
       "Decrease the value of the ranged-integer WIDGET."
       (interactive (list (widget-at)))
       (widget-ranged-integer-change widget 'down))

Inspecting Widgets
******************

There is a separate package to browse widgets, in wid-browse.el.  This is intended to help programmers who want to examine the content of a widget.  The browser shows the value of each keyword, but uses links for certain keywords such as :parent, which avoids printing cyclic structures.

 -- Command: widget-browse WIDGET
     Create a widget browser for WIDGET.

     When called interactively, prompt for WIDGET.

 -- Command: widget-browse-other-window WIDGET
     Create a widget browser for WIDGET and show it in another window.

     When called interactively, prompt for WIDGET.

 -- Command: widget-browse-at POS
     Create a widget browser for the widget at POS.

     When called interactively, use the position of point.

In addition, there's a function to describe the widget at point.

 -- Command: widget-describe &optional widget-or-pos
     Describe the widget at point.

     When called from Lisp, WIDGET-OR-POS might be the widget to describe or a buffer position where a widget is present.  If WIDGET-OR-POS is nil, the widget to describe is the widget at point.

     This command sets up a help buffer for providing information about the widget, mainly its :action and :mouse-down-action functions, and provides links to describe it in more detail using the widget-browse commands described above.

Widget Minor Mode
*****************

There is a minor mode for manipulating widgets in major modes that don't provide any support for widgets themselves.  This is mostly intended to be useful for programmers doing experiments.

 -- Command: widget-minor-mode
     Toggle minor mode for traversing widgets. With arg, turn widget mode on if and only if arg is positive.

 -- Variable: widget-minor-mode-keymap
     Keymap used in widget-minor-mode.

Utilities
*********

Here we describe some utility functions that don't really have a place earlier in this manual.

 -- Function: widget-prompt-value widget prompt [ value unbound ]
     Prompt for a value matching WIDGET, using PROMPT. The current value is assumed to be VALUE, unless UNBOUND is non-nil.

     Converts WIDGET before prompting, and for prompting it uses the :prompt-value function.  This function returns the user ``answer'', and it's an error if that answer doesn't match the widget, as with the :match function.

     If the answer matches the widget, returns the answer.

 -- Function: widget-get-sibling widget
     Get the item which WIDGET should toggle. This is only meaningful for radio buttons or checkboxes in a list.

 -- Function: widget-choose title items &optional event
     Prompt the user to choose an item from a list of options.

     TITLE is the name of the list of options.  ITEMS should be a menu, with its items in the simple format or in the extended format. See Defining Menus (the Emacs Lisp Reference Manual).  Independently of the format, you don't have to provide a title for the menu, just pass the desired title in TITLE.  The optional EVENT is an input event.  If EVENT is a mouse event and the number of elements in ITEMS is less than the user option widget-menu-max-size, then widget-choose uses a popup menu to prompt the user.  Otherwise, widget-choose uses the minibuffer.

     When ITEMS is a keymap menu, the returned value is the symbol in the key vector, as in the argument of define-key (see Changing Key Bindings (the Emacs Lisp Reference Manual)).  When ITEMS is a list whose selectable items are of the form (NAME . VALUE) (i.e., the simplified format), then the return value is the VALUE of the chosen element.

 -- Function: widget-image-find image
     Create a graphical button from IMAGE, an image or a file name sans extension.

     If IMAGE is a file name, the file should be in widget-image-directory, or in a place where find-image will find it.

 -- Function: widget-image-insert widget tag image
     As part of WIDGET, insert the text TAG or, if supported, the image IMAGE.

     IMAGE should be as described in widget-image-find.

 -- Function: widget-echo-help pos
     Display help-echo text for the widget at POS.

     Uses the value of :help-echo.  If it is a function, it calls it to get a string.  Otherwise, it evals it.

Customization
*************

This chapter is about the customization options for the Widget library, for the end user.

 -- Face: widget-documentation
     Face used for documentation text.

 -- Face: widget-field
     Face used for editable fields.

 -- Face: widget-button
     Face used for buttons.

 -- Face: widget-button-pressed
     Face used for pressed buttons.

 -- Face: widget-inactive
     Face used for inactive widgets.

 -- User Option: widget-mouse-face
     Face used for highlighting a button when the mouse pointer moves across it.

     The default value is highlight.

 -- User Option: widget-image-directory
     Directory where Widget should look for images.

     Widget will look here for a file with the same name as specified for the image, with either a .xpm (if supported) or .xbm extension.

 -- User Option: widget-image-enable
     If non-nil, allow images to appear on displays where they are supported.

 -- User Option: widget-image-conversion
     An alist to convert symbols from image formats to file name suffixes.

     Each element is a cons cell (FORMAT . SUFFIX), where FORMAT is a symbol that represents an image format and SUFFIX is its correspondent suffix.

 -- User Option: widget-button-prefix
     String to prefix buttons.

 -- User Option: widget-button-suffix
     String to suffix buttons.

 -- User Option: widget-push-button-prefix
     String to prefix push buttons.

 -- User Option: widget-push-button-suffix
     String to suffix push buttons.

 -- User Option: widget-link-prefix
     String to prefix links.

 -- User Option: widget-link-suffix
     String to suffix links.

 -- User Option: widget-choice-toggle
     If non-nil, toggle when there are just two options.

     By default, its value is nil.

 -- User Option: widget-documentation-links
     If non-nil, add hyperlinks to documentation strings.

 -- User Option: widget-documentation-link-regexp
     A regexp that matches potential links in documentation strings.  The link itself should match to the first group.

 -- User Option: widget-documentation-link-p
     A predicate function to test if a string is useful as a link.  The function is called with one argument, a string, and should return non-nil if there should be a link for that string.

     By default, the value is intern-soft.

 -- User Option: widget-documentation-link-type
     A symbol that represents a widget type to use for links in documentation strings.

     By default, the value is documentation-link.

 -- User Option: widget-menu-max-size
     Maximum size for a popup menu.  By default, its value is 40.

     If a function ask you to choose from a menu that is larger than this value, it will use the minibuffer.

 -- User Option: widget-menu-max-shortcuts
     Largest number of items for which it works to choose one with a character.

     For a larger number, use the minibuffer.

 -- User Option: widget-menu-minibuffer-flag
     Whether to use the minibuffer to ask for a choice.

     If nil, the default, read a single character.

Wishlist
********

  * It should be possible to add or remove items from a list with C-k and C-o (suggested by RMS).

  * The [INS] and [DEL] buttons should be replaced by a single dash (-).  The dash should be a button that, when invoked, asks whether you want to add or delete an item (RMS wanted to git rid of the ugly buttons, the dash is my idea).

  * The menu-choice tag should be prettier, something like the abbreviated menus in Open Look.

  * Finish :tab-order.

  * Make indentation work with glyphs and proportional fonts.

  * Add commands to show overview of object and class hierarchies to the browser.

  * Find a way to disable mouse highlight for inactive widgets.

  * Find a way to make glyphs look inactive.

  * Add widget widget for editing widget specifications.

  * Find clean way to implement variable length list. See TeX-printer-list for an explanation.

  * C-h in widget-prompt-value should give type specific help.

  * Add a mailto widget.

GNU Free Documentation License
******************************

     [file doclicense.texi not included]

Index
*****

This is an alphabetical listing of all concepts, functions, commands, variables, and widgets described in this manual.